pro Graff_hard, pdefs, no_set=no_set

;+
; GRAFF_HARD
;	Make a hardcopy
;
; Usage:
;	graff_hard, pdefs
;
; Argument:
;	pdefs	struct	in/out	The plot definition structure.
;
; Keyword:
;	no_set		input	If set and non-zero, then don't call
;				hardopts to set up the options.
;				
; History:
;	Carved from graffer: 17/8/95; SJT
;	Added no_set key: 8/9/95; SJT
;-

tname = pdefs.name
if (((dp = strpos(tname, '.'))) ne -1) then  $
  tname = strmid(tname, 0, dp)
tname = pdefs.dir+tname

h = pdefs.hardset
if (not keyword_set(no_set)) then begin
    ido = hardopts(h, pdefs.ids.graffer, tname)
    if (ido eq -1) then return
endif

pdefs.hardset = h

cpl = float(!D.x_size)/float(!D.x_ch_size)

dev = !D.name
set_plot, 'ps'


!P.font = 0

if (h.eps) then file = tname+'.eps' $
else file = tname+'.ps'

device, file = file,  encapsu = h.eps, bits = 8*h.colour, color = $
  h.colour, /helvetica
if (h.colour) then s_colours

if (h.eps) then begin 
    if h.orient then device, /portrait $
    else device, /landscape
endif else if (h.orient) then device, /portrait, yoffset = 3. $
else  device, /landscape, yoffset = h.size(0)+3 

device, xsize = h.size(0), ysize = h.size(1)

ncpl = float(!D.x_size)/float(!D.x_ch_size)
csiz = ncpl/cpl

plot_object, pdefs, /no_null, charsize = csiz

if (h.timestamp and not h.eps) then begin
    st = string(getenv('USER'), systime(), pdefs.version, $
                format = "(A,' @ ',A,' from V',I0,'.',I2.2)")
    xyouts, /norm, .98, .01, st, charsize = 0.67, align = 1.0
endif

device, /close
set_plot, dev
if (not h.eps) then spawn, h.action(0)+' '+tname+'.ps '+h.action(1) $
else graff_msg, pdefs.ids.message, 'Output file is: '+file

!P.font = -1

s_colours

end