PRO boxdev, hh, mm, wave, maxv, sdate, img, background, c_bar
;
; Annotates the image on the screen by placing it in a larger window
;
; INPUTS:
;   hh      UT 2-digit hours                       LONG
;   mm      UT 2-digit minutes                     LONG
;   wave    Wavelength                             LONG
;   maxv    Maximum value - Rayleighs              FLOAT
;   sdate   Date                                   STRING
;   img     The image                              BYTARR(800,800)
; OUTPUTS:
;   background                                     BYTARR(900,900)
;   c_bar   The color bar                          BYTARR(350,25)
;   fname   Name for the PostScript file           STRING

background = bytarr(900,900)
imgx = 50
imgy = 40
background(imgx:imgx+799, imgy:imgy+799) = img(*,*)

; MAKE COLOR BAR
cb_tall = 25
c_bar = bytarr(350,cb_tall)
for i=0,349 do begin
   c_bar(i,*) = fix((float(i)/349.0)*256)
endfor
c_white = 255
c_bar(0:1,*) = c_white
c_bar(348:349) = c_white
c_bar(*,0:1) = c_white
c_bar(*,cb_tall-2:cb_tall-1) = c_white
cb_bot = imgy + 10 + 800
cb_top = cb_bot + cb_tall - 1
; PUT COLOR BAR INTO BACKGROUND
background(500:849,cb_bot:cb_top) = c_bar(*,*)

window,xsi=900,ysi=900
tv,background

font = '!5'

; ADD THE MLT LABELS
x = 10
y = imgy + 393
xyouts,x,y,'18',/device
xyouts,x,y-20,'MLT',/device
x = 860
xyouts,x,y,'06',/device
xyouts,x,y-20,'MLT',/device
x = imgx + 365
y = 10
xyouts,x,y,'00 MLT',/device

; ADD THE LATITUDES
x = imgx + 365
y = imgy + 800 - 25
xyouts,x,y,'70!9%!X',/device
y = imgy + 600 - 25
xyouts,x,y,'80!9%!X',/device

x = imgx
y = 875
str = STRING(FORMAT='(I5)',wave)
str = STRTRIM(str,2)
xyouts,x,y,'POLAR '+str + ' A IMAGES',/device
Y = y - 20
xyouts,x,y,'PACE GEOMAGNETIC COORDINATES',/device

; ANNOTATE THE COLOR BAR
x = 675
y = cb_top + 5
xyouts,x,y,'RAYLEIGHS',ALIGNMENT=0.5,/DEVICE
x = 500
xyouts,x,y,'0',ALIGNMENT=0.5,/device
str = STRING(FORMAT='(I5)',maxv)
str = STRTRIM(str,2)
x = 849
xyouts,x,y,str,ALIGNMENT=0.5,/DEVICE

; ADD THE UT LABEL
strh = STRING(FORMAT='(I2)',hh)
strm = STRING(FORMAT='(I2)',mm)
if (hh lt 10) then STRPUT,strh,'0',0
if (mm lt 10) then STRPUT,strm,'0',0
str = strh + strm + ' UT'
x = 819 - 10
y = imgy + 10
xyouts,x,y,str,ALIGNMENT=1.0,/DEVICE

; ADD THE DATE
x = imgx + 10
xyouts,x,y,sdate,/device
background = tvrd(0,0,900,900)
end