PRO WDOSCOG
;+
; NAME:
;	WDOSCOG
;
; PURPOSE:
;	This procedure generates a scalogram and plots it. The scalogram is 
;	a moderately well-established term for (a plot usually, of) the wavelet 
;	coefficients as a function of the two independent variables, or indices 
;	in the discrete case, scale and location.  It is common to use the absolute 
;	value, or even the log of the absolute value in practice. This imple-
;	mentation uses the output coefficients from the discrete wavelet
;	transform in a surface plot representation.
;
; CATEGORY:
;	Wavelets.
;
; CALLING SEQUENCE:
;	WDOSCOG
;
; INPUTS: (via COMMON)
;	X_work:	1-d signal array	
;	QMF: Quadrature Mirror Filter
;
; OUTPUTS:
;	The scalegram plotted to the screen.
;
; COMMON BLOCKS:
; COMMON WWB_COMMON, $
;	TEXT_ANNOUNCE, wd, sig, len, st, noise_type, noise_lev, $
;	QMF, LD, shrinkage_type, WaveType, ParVal
;
; EXAMPLE:
;	Truncate sig array appropriately and get QMF
;	IDL> WINTWAVE, sig, WaveType, ParVal, QMF, LD
;	Call scalogram
;	IDL> WDOSCOG
;
; SEE ALSO:
;	wintwave (necessary for this procedure)
;
;
; MODIFICATION HISTORY:
; 	Written by:	Amara Graps		August, 1995
;	(Translated from Donoho, Scargle et al's MatLab Wavelab routines.)
;- 
COMMON WWB_COMMON, $
	TEXT_ANNOUNCE, wd, sig, len, st, noise_type, noise_lev, $
	QMF, LD, shrinkage_type

stitle='Scalogram of '+st 

x_work = sig
TT = WSIGTYPE(x_work, olen, error)

CASE error OF
	1: BEGIN
		;Valid array or matrix
	
		CASE TT OF
			'I': BEGIN
				;Image
				WIDGET_CONTROL, TEXT_ANNOUNCE, SET_VALUE='Scalogram Not Implemented for 2D Data.'				
				END	;image
				
			'S': BEGIN
				;Signal
				;Calculate wavelet coefficients (Periodized Orthononormal Fast Wavelet Transform)
				wc = WFWTPO(x_work,LD,QMF)

				;Set up the plot window
				;pt and d are dummy values
				pt = '' & d = FLTARR(2)
				WPLOTIT, pt, 3, d

				;Do Multi-resolution surface plot
				scal = 0	;use the default in wplmsurf
				WPLMSURF, wc,LD,scal,qmf, st
				
				END	;signal/data array						
		ENDCASE	;TT

	
		END	;valid array or matrix
		
	ELSE: PRINT, 'Not valid data/signal array or matrix!'

ENDCASE		;error

; Algorithm Source:  WaveLab Version 0.600
; WaveLab WWW site: http://playfair.stanford.edu/ 
; WaveLab Questions? e-mail wavelab@playfair.stanford.edu

 
End  ;of WDOSCOG
;***************************************************