function WHYBRTHR, y
;+
;NAME:
;	WHYBRTHR
;
;PURPOSE:
;	To perform Shrinkage to Wavelet Coefficients via 
;	Adaptive Threshold Selection Using Principle of Stein's 
;	Unbiased Risk Estimate Variant without Rigorous Proof 
;
;CATEGORY:
;	Wavelets.
;
;CALLING SEQUENCE:
;	xhat = WHYBRTHR(Y)
;
;INPUTS:
;      y :    Noisy Data with Std. Deviation = 1 
;
;OUTPUTS:
;      xhat : Estimate of mean vector 
;
;EXAMPLE:
;
;NOTES:
; See Donoho, D.L. and Johnstone, I.M. ``Adapting 
;   to Unknown Smoothness by Wavelet Shrinkage'' 
;
;SEE ALSO: 
;     wmhybrid, wdoshrnk
;
;
;MODIFICATION HISTORY:
; 	Written by:	Amara Graps		December, 1994
;Translated from MatLab Wavelab routine: hybridthresh.m
;-

n = WDYADLNG(y,J) 
magic = SQRT(2*ALOG(n)) 
eta = (WNNORM(y)^2 - n)/n 
crit = J^(1.5)/SQRT(n) 

CASE 1 OF
	( eta LT crit): BEGIN
		xhat = WSOFTTHR(y,magic) 	
		END	;eta LT crit
		
	ELSE: BEGIN
    	T  = WSMIN(WVALSTHR(y), magic) 
		xhat  = WSOFTTHR(y ,T) 
		END	;else
ENDCASE
     
     
;    
; Algorithm Source:  WaveLab Version 0.600
; WaveLab WWW site: http://playfair.stanford.edu/ 
; WaveLab Questions? e-mail wavelab@playfair.stanford.edu
;    
     
 
RETURN, xhat  
END  
;***************************************************