PRO WVLOADCT, col_table
;+
; NAME:
; 	WVLOADCT
;
; PURPOSE:
;	This procedure sets up the color table and color variables
;	used in the WaveLab plotting routines.
;
; CATEGORY:
;	Wavelets
;
; CALLING SEQUENCE:
;    WVLOADCT, col_table
;
; INPUTS:
;    col_table:  integer
;
; OUTPUTS:
;    Color table and color variables set (put in COMMON)
;
; EXAMPLE:
;	WVLOADCT, 1
;	(Loading table BLUE/WHITE)
;
; NOTES:
;	Put the following common block in your program to use the
;	pre-defined color variables 
;	(i.e., the call: PLOT, x, color = yellow should work).
;
;	COMMON Wave_color, $
;     		max_color, max_image, $
;      		white, yellow, lavender, aqua, pink, green, red, orange, blue, $
;      		lt_gray, med_green, brown, olive, purple, dk_gray, black
;
; MODIFICATION HISTORY:
; 	Written by:	Amara Graps		November, 1994
;	(lifted from IDL's tour_loadct.pro)
;-

COMMON Wave_color, $
      max_color, max_image, $
      white, yellow, lavender, aqua, pink, green, red, orange, blue, $
      lt_gray, med_green, brown, olive, purple, dk_gray, black

max_color = (!D.N_Colors - 1L) < 255L

IF (max_color GE 2L) THEN BEGIN
   white = (max_color - 1L)  > 0L
   yellow = (max_color - 2L) > 0L
   lavender = (max_color - 3L) > 0L
   aqua = (max_color - 4L) > 0L
   pink = (max_color - 5L) > 0L
   green = (max_color - 6L) > 0L
   red = (max_color - 7L) > 0L
   orange = (max_color - 8L) > 0L
   blue = (max_color - 9L) > 0L
   lt_gray = (max_color - 10L) > 0L
   med_green = (max_color - 11L) > 0L
   brown = (max_color - 12L) > 0L
   olive = (max_color - 13L) > 0L
   purple = (max_color - 14L) > 0L
   dk_gray = (max_color - 15L) > 0L
   black = (max_color - 16L) > 0L
ENDIF ELSE BEGIN
   white = 1L
   yellow = 1L
   lavender = 1L
   aqua = 1L
   pink = 1L
   green = 1L
   red = 1L
   orange = 1L
   blue = 1L
   lt_gray = 1L
   med_green = 0L
   brown = 0L
   olive = 0L
   purple = 0L
   dk_gray = 0L
   black = 0L
ENDELSE

IF (max_color GE 2L) THEN BEGIN
   IF (max_color GE 16L) THEN BEGIN
      Loadct, col_table, /Silent
      Stretch, 0L, (max_color - 16L)
   ENDIF

   Tvlct,   0,   0,   0, black
   Tvlct,  55,  55,  55, dk_gray
   Tvlct, 100,  30,  80, purple
   Tvlct,  55,  55,   0, olive
   Tvlct,  80,  30,  30, brown
   Tvlct,  55, 130, 100, med_green
   Tvlct, 180, 180, 180, lt_gray
   Tvlct,  80,  80, 255, blue
   Tvlct, 255, 180,  80, orange
   Tvlct, 255,  30,  30, red
   Tvlct,  55, 255,  55, green
   Tvlct, 255, 100, 150, pink
   Tvlct,  80, 255, 255, aqua
   Tvlct, 200, 180, 255, lavender
   Tvlct, 255, 255,   0, yellow
   Tvlct, 255, 255, 255, white

   Tvlct,   0,   0,   0, 0
ENDIF

EMPTY

RETURN
END ;  pro WVLOADCT