PRO i2b,nA,lambda,b,db
;
; This procedure accepts an array of 5 picoammeter readings (suitably
; corrected and averaged) and returns three arrays: the standard
; wavelengths used for the calibration, the corresponding PLBS
; brightnesses (in kR/A), and the brightness uncertainties, assuming
; an uncertainty of 0.001 nA in each photodiode current measurement.
;
; The constant 0.2646 results as follows:
;
;	         4 * PI * 1E-9 * 1E-9 * 1E-9 * 1E-1
;	0.2646 = -------------------------------------------------
;	         h(6.62607E-34) * c(2.9979E+8) * dOMEGA(2.391E-2)
;
; The two factors of 1E-9 are:
; - to convert current (nA) to current (A)
; - to convert wavelength (nm) to wavelength (m)
; The factor 4 * PI * 1E-9 is:
; - to convert photons to kilorayleighs ( ph => kR )
; The factor 1E-1 is:
; - to convert kR/nm (implicit in using wavelength in nm) to kR/A
;
; Notes added 950629 by DPS, ISR.
;
lambda=[558.3,630.64,694.09,740.05,795.36] ; measured filter cw (nm)
Rlambda=[0.339,0.417,0.474,0.511,0.547] ; photodiode A responsivities
tlambda=[0.619,0.628,0.589,0.895,0.818] ; filter peak transmissions
dlambda=[8.15,5.58,1.00,7.89,2.80] ; filter bandwidths (nm)
;
; Note that wavelengths in nm are used for calculating brightnesses
; in kR/A, and then converted to A for fitting and plotting.
;
b=0.2646*na*lambda/(Rlambda*tlambda*dlambda)
db=0.2646*REPLICATE(0.001,5)*lambda/(Rlambda*tlambda*dlambda)
lambda=10.*lambda
RETURN
END