; CHECKIMG.PRO
;
; DPS, CNSR, July 1992
;
; This program gets the names of all images files generated during
; the thermal test in July 1992, reads the image files and gets
; the header contents, and writes a line to a file summarizing the
; date, time, camera internal temperature, maximum-valued image
; pixel, and number of image pixels with values exceeding 16383.
; This outcome would only occur if the camera electronics unit
; malfunctioned at low temperatures.  The file generated from all
; images should allow diagnosis of the CE temperature at which this
; type of malfunction begins to occur.
;
allf=FINDFILE('*.[0-9]??')
numf=N_ELEMENTS(allf)
PRINT,STRING(numf,FORMAT='(I3," files found")')
OPENW,unit,'imgstats.dat',/GET_LUN
PRINTF,unit, $
       'File         Date       Time     TEI PixMax ImgMax PixMin ImgMin #>16K'
PRINTF,unit, $
       '----------------------------------------------------------------------'
FOR i=0,numf-1 DO BEGIN
    rdkimg,allf(i),hb,img
    kih=gethd(hb)
    date=kih.misc.dt
    time=kih.misc.tm
    tint=kih.misc.temp.tei.mean
    pmax1=kih.misc.pixel_max
    pmin1=kih.misc.pixel_min
    pmax2=MAX(img,MIN=pmin2)
    ngt16k=TOTAL(img GT 16383)
    dst=STRING(date.(0),date.(1),date.(2), $
               FORMAT='(I2,"/",I2,"/",I4)')
    tst=STRING(time.(0),time.(1),time.(2), $
               FORMAT='(I2,":",I2,":",I2)')
    outst=allf(i)+' '+dst+' '+tst+' '+ $
          STRING(tint,pmax1,pmax2,pmin1,pmin2,ngt16k, $
                 FORMAT='(I3,5(1X,I6))')
    PRINTF,unit,outst
    PRINT,i,outst
ENDFOR
CLOSE,unit & FREE_LUN,unit
END