PRO compcals,cam
;+
; INPUT:
;	cam - Polar Camera number (0 or 1)
; OUTPUT:
;	none
; SIDE EFFECTS:
;       Produces a plot of the calibration histories of the various
;	channels of the specified Polar Camera imager.
; METHOD:
;       Reads a text file with 6 columns, one per calibration run,
;       giving in order the YYMMDD of the run, and the sensitivities
;       for each of the five imager channels, expressed in
;       Rayleigh-seconds/DN (gain 4).  Converts the YYMMDD to Julian
;       dates and plots the time history of the sensitivity at each
;	channel versus date.
; MODIFICATION HISTORY:
;	18 May 1994, D. P. Steele.  Written.
;-

@isitdos

rdcols,'/jasper/cnsr3_data1/cal'+STRTRIM(cam,2),n,ymd,s0,s1,s2,s3,s4

ymd=ROUND(ymd)
y=1900+ymd/10000
m=(ymd MOD 10000)/100
d=ymd MOD 100
jd0=ymd2jd(y(0),1,1)
jd=ymd2jd(y,m,d)-jd0+1
minjd=MIN(jd,MAX=maxjd)
jdrange=20*[FLOOR(minjd/20.),CEIL(maxjd/20.)]

alls=[s0,s1,s2,s3,s4]
smax=20*CEIL(MAX(alls(WHERE(alls)),MIN=smin)/20.)+20

PRINT,'Channel   Mean      Std. Dev.'

PLOT,jd,s0,XRANGE=jdrange,/XSTYLE,YRANGE=[0,smax],/YSTYLE $
	  ,XTITLE='Day Number ('+STRTRIM(y(0),2)+')' $
          ,YTITLE='Sensitivity (Rayleigh-seconds per DN (gain 4)' $
          ,TITLE='Summary of Polar Camera Calibrations - Camera ' $
		 +STRTRIM(cam,2) $
          ,PSYM=1
psym=[1]
filt=[0]
PRINT,0,mean(s0),stdev(s0),FORMAT='(I1,4X,2F10.1)'
IF TOTAL(s1) GT 0 THEN BEGIN
    OPLOT,jd,s1,PSYM=2
    psym=[psym,2]
    filt=[filt,1]
    PRINT,1,mean(s1),stdev(s1),FORMAT='(I1,4X,2F10.1)'
    ENDIF
IF TOTAL(s2) GT 0 THEN BEGIN
    OPLOT,jd,s2,PSYM=4
    psym=[psym,4]
    filt=[filt,2]
    PRINT,2,mean(s2),stdev(s2),FORMAT='(I1,4X,2F10.1)'
    ENDIF
IF TOTAL(s3) GT 0 THEN BEGIN
    OPLOT,jd,s3,PSYM=5
    psym=[psym,5]
    filt=[filt,3]
    PRINT,3,mean(s3),stdev(s3),FORMAT='(I1,4X,2F10.1)'
    ENDIF
IF TOTAL(s4) GT 0 THEN BEGIN
    OPLOT,jd,s4,PSYM=6
    psym=[psym,6]
    filt=[filt,4]
    PRINT,4,mean(s4),stdev(s4),FORMAT='(I1,4X,2F10.1)'
    ENDIF

xdvpos=!P.CLIP(0)
ydvpos=!P.CLIP(3)
npos=CONVERT_COORD([xdvpos,ydvpos],/DEVICE,/TO_NORMAL)
npos=npos(0:1)
nmpos=STRPOS(filters(5*cam+filt),'nm')+2
labels=STRMID(filters(5*cam+filt),0,MAX(nmpos))
FOR il=0,N_ELEMENTS(filt)-1 DO $
    labels(il)=STRMID(labels(il),0,nmpos(il))
lines=filt
legend,labels,psym=psym,position=npos,/horizontal ;$
;     ,charsize=0.5,spacing=0.6

RETURN
END