PRO ct1,yr,mo,day,oneday=oneday

; This procedure used to be a program, but it's needed as a
; procedure.

; Internal temperatures and times

rdcols,'tei5',nei,time,tei
tei=tei/10.

; External temperatures

rdcols,'tee5',nee,junk,tee
tee=tee/10.

; CCD temperatures

rdcols,'tcf5',ncf,junk,tcf
tcf=tcf/10.

; Filter wheel temperatures

rdcols,'tfw5',nfw,junk,tfw
tfw=tfw/10.

; Dome temperatures

rdcols,'td5',nd,junk,td
td=td/10.

; Heater temperatures

rdcols,'heater5',nheater,junk,heater
heater=heater/10.

nels=nei<nee<ncf<nfw<nd<nheater

mx=FLTARR(5)
mx(0)=MAX(tee) & mx(1)=MAX(tei) & mx(2)=MAX(tfw) & mx(3)=MAX(td)
mx(4)=MAX(tcf)

PRINT,MIN(time,MAX=mt),mt, $
      FORMAT='("Time spans ",F4.1," - ",F4.1," hrs UT")'

xt='UT (hours, '+ymd2date(yr,mo,day,format='d$ n$ y$')+')'
pt='Camera 1 Temperature Parameters, ' $
   +ymd2date(yr,mo,day,format='d$ n$ y$')

IF KEYWORD_SET(oneday) THEN BEGIN
    IF mt GT 24. THEN BEGIN
	PRINT,'Only data from the first 24 hours UT will be plotted!'
	PRINT,'Divide this temperature log file into separate days'
	PRINT,'to see the data from later times!'
	ENDIF

    ; Truncate all data arrays to the first UT day represented
    le24=WHERE(time LE 24,nlt24)
    nels=nels<nlt24
;   i=N_ELEMENTS(le24)
    time=time(le24)
    tfw=tfw(le24)
    tei=tei(le24)
    td=td(le24)
    tee=tee(le24)
    tcf=tcf(le24)
    heater=heater(le24)

    PLOT,time,tee,XRANGE=[0,24],/XSTYLE $
	 ,YRANGE=[-50,MAX([40,mx])],/YSTYLE $
         ,XTITLE=xt,TITLE=pt,PSYM=3 $
	 ,YTITLE="Temperature (!9%!xC), Heater Status (DN/10)" $
         ,XTICKS=5,XTICKV=INDGEN(5)*6,XMINOR=6
    ENDIF ELSE PLOT,time,tee,XRANGE=[MIN(time),mt],/XSTYLE $
	           ,YRANGE=[-50,MAX([40,mx])],/YSTYLE $
                   ,XTITLE=xt,TITLE=pt,PSYM=3 $
	           ,YTITLE="Temperature (!9%!xC), Heater Status (DN/10)"

IF nels LT 2 THEN BEGIN
    MESSAGE,STRING(nels,FORMAT='(I1," samples - too few to plot")') $
           ,/INFORMATIONAL
    RETURN
    ENDIF

PLOTS,[time(0),time(nels-1)],[tee(0),tee(nels-1)],PSYM=1
OPLOT, time, tei,PSYM=3
PLOTS,[time(0),time(nels-1)],[tei(0),tei(nels-1)],PSYM=2
OPLOT, time, tfw,PSYM=3
PLOTS,[time(0),time(nels-1)],[tfw(0),tfw(nels-1)],PSYM=4
OPLOT, time, tcf,PSYM=3
PLOTS,[time(0),time(nels-1)],[tcf(0),tcf(nels-1)],PSYM=5
OPLOT,time,td,PSYM=3
PLOTS,[time(0),time(nels-1)],[td(0),td(nels-1)],PSYM=6
OPLOT, time, heater
PLOTS,[time(0),time(nels-1)],[heater(0),heater(nels-1)],PSYM=7

items=['tfw','tei','td','tee','tcf','heater']
psym=[4,2,6,1,5,7]
xdvpos=!P.CLIP(0)
ydvpos=!P.CLIP(3)
npos=CONVERT_COORD([xdvpos,ydvpos],/DEVICE,/TO_NORMAL)
npos=npos(0:1)
legend,items,psym=psym,position=npos
timestmp

RETURN
END