PRO geo_info,srcname,geoname,cam,filt,year,month,day,shr,smin,ssec,ehr $
	    ,emin,esec,eht,vRbg,site,exptime,fullscale $
	    ,annotate=annotate,grid=grid,zoom=zoom,sat=sat
;+
; NAME:
;	GEO_INFO
;	
; PURPOSE:
;       Writes information about a .geo file into an associated
;       text file.  The .geo file contains Polar Camera images that
;       have been mapped to geographic coordinates at an assumed
;       height that depends on the emission feature imaged.  File
;       name size constraints on DOS platforms prevent the use of
;       descriptive (i.e., long) file names, so the information is
;	saved to another file.
;	
; CATEGORY:
;	
; CALLING SEQUENCE:
;	GEO_INFO, SRCNAME, GEONAME, CAM, FILT, YEAR, MONTH, DAY, SHR $
;		, SMIN, SSEC, EHR, EMIN, ESEC, EHT, VRBG, SITE, EXPTIME $
;		, FULLSCALE, ANNOTATE = ANNOTATE, GRID = GRID, ZOOM = ZOOM
;               , SAT = SAT
;	
; INPUTS:
;       SRCNAME: Full pathname of the file containing the images
;		to be transformed.
;       GEONAME: Full pathname of the .geo file to be created by
;		POCAFLIC.PRO.
;	CAM:	Camera number (0/1).
;	FILT:	Filter number (0..4).
;	YEAR:	Year of observation (either 2 or 4 digits).
;	MONTH:	Month number of observation.
;	DAY:	Day number of observation (reckoned by Universal Time).
;	SHR, SMIN, SSEC: Hour, minute, second (UT) of start of first image.
;	EHR, EMIN, ESEC: Hour, minute, second (UT) of start of last image.
;	EHT:	Assumed height of emission (km).
;       VRBG:   Zenith brightness (Rayleighs) of an assumed uniformly-
;               emitting layer whose brightness is subtracted from
;		each image.
;       SITE:   String giving the location of the Polar Camera at
;		the time of the observations.
;       EXPTIME: The exposure time of the images to be stored in
;               the .geo file; either 0 (if all available exposure
;               times accepted) or non-zero if only one exposure
;		time accepted.
;       FULLSCALE: The value (in Rayleighs) of the brightness
;               corresponding to the top of the colour table used.
;		Brightnesses greater than this are saturated.
;	
; KEYWORD PARAMETERS:
;       ANNOTATE: True if the mapped images are labelled with date,
;               time, etc.
;       GRID:   String containing [gG] if the mapped images are
;               decorated with a coordinate grid, and/or [cC] if
;		they are decorated with coastlines.
;       ZOOM:   True if the coordinate grid has been expanded to
;               show greater detail in images mapped to heights
;		less than 300 km.
;       SAT:    Contains the standard 2-line element name of a
;               satellite if that satellite's footprint is overplotted
;		on the transformed images.
;
; OUTPUTS:
;	None.
;	
; COMMON BLOCKS:
;	None.
;	
; SIDE EFFECTS:
;	A text file is created, containing the above information.
;
; RESTRICTIONS:
;	None that I can think of.
;
; PROCEDURE:
;	Straightforward.
;
; MODIFICATION HISTORY:
;	Modified 950316 by D P Steele from PGM_INFO.PRO.
;-

; Open the file to hold the information about the .geo file.

geiname=geoname
STRPUT,geiname,'i',STRLEN(geiname)-1
OPENW,infounit,geiname,/GET_LUN

; Write information about the .geo file

PRINTF,infounit,'The image source file name is ',srcname
PRINTF,infounit,'The .geo file name is ',geoname
PRINTF,infounit,'Created at '+SYSTIME()
PRINTF,infounit,'Images from camera '+STRTRIM(cam,2)+', filter ' $
	       +STRTRIM(filt,2)
PRINTF,infounit,ymd2date(year,month,day,format='d$ n$ y$')
PRINTF,infounit,'Start with first image after ' $
               +strsec(ROUND((shr*60.+smin)*60.+ssec))+' UT'
PRINTF,infounit,'Finish with last image before ' $
               +strsec(ROUND((ehr*60.+emin)*60.+esec))+' UT'
PRINTF,infounit,'Assumed emission height '+STRTRIM(eht,2)+' km'
IF vRbg GT 0. THEN BEGIN
    PRINTF,infounit,'Subtracted a uniform emitting layer of ' $
		    +STRTRIM(vRbg,2)+' R brightness'
    PRINTF,infounit,'Layer height '+STRTRIM(eht,2)+' km'
    ENDIF
PRINTF,infounit,'Images acquired at '+site
IF exptime GT 0 $
    THEN PRINTF,infounit,'Image exposure time ',exptime,' s' $
			,FORMAT='(A,F4.1,A)' $
    ELSE PRINTF,infounit,'All exposure times accepted (probably 10.0s and 60.0 s)'
IF fullscale GT 0 $
    THEN PRINTF,infounit,'Full scale image brightness',fullscale,' R' $
	       ,FORMAT='(A,F6.0,A)' $
    ELSE PRINTF,infounit,'Each image scaled independently to 99.9th percentile brightness'
decorated='Images '
IF STRPOS(grid,'g') NE -1 THEN decorated=decorated+'gridded'
IF KEYWORD_SET(annotate) THEN decorated=decorated+' and labelled'
IF STRPOS(grid,'C') NE -1 $
    THEN decorated=decorated+' and overlaid with coastlines'
PRINTF,infounit,decorated
IF sat NE '' $
    THEN PRINTF,infounit,sat+' footprint overplotted on images'

; Close the file

FREE_LUN,infounit

RETURN
END