PRO plotpkr,filename,plot_title

rdascpkr,filename,pkr,alt,label,nalt,nemis

l3=nemis/3
menu=STRARR(l3)
FOR i=0,l3-1 DO $
    menu(i)=STRING(i,label(i),MAX(pkr(*,i)) $
		  ,i+l3,label(i+l3),MAX(pkr(*,i+l3)) $
                  ,i+2*l3,label(i+2*l3),MAX(pkr(*,i+2*l3)) $
		  ,FORMAT='(3("(",I2,")",A10,2X,G8.3,2X))')
PRINT,menu

nplots=0
REPEAT BEGIN

    PRINT,'Enter the number(s) of the emissions to be plotted'
    PRINT,'(enter an illegal value to quit)'
    nem=''
    READ,nem
    ems=STR_SEP(nem,' ')

    prof=FLTARR(nalt)
    quit=0
    FOR j=0,N_ELEMENTS(ems)-1 DO BEGIN
	f=isnumber(ems(j),emn)
	IF f NE 0 THEN BEGIN
	    goodems=(0 LE emn) AND (emn LE nemis-1)
	    IF goodems THEN prof=prof+pkr(*,emn) ELSE quit=1
        ENDIF
    ENDFOR

    IF NOT quit THEN BEGIN
        IF nplots GT 0 THEN $
	    OPLOT,prof,alt,LINESTYLE=nplots $
	    ELSE PLOT_OI,prof,alt,XRANGE=[0.1,MAX(prof)] $
                        ,YRANGE=[80,300],YSTYLE=1 $
                        ,XTITLE='Volume Production Rate ( cm!e-3!n s!e-1!n )' $
                        ,YTITLE='Altitude ( km )' $
                        ,TITLE=plot_title

        PRINT,'Enter the curve label'
        elabel=''
        READ,elabel
        PRINT,'Enter its data coordinates'
        READ,xlabel,ylabel

        XYOUTS,xlabel,ylabel,elabel,ALIGNMENT=0.
        nxy=CONVERT_COORD([xlabel,ylabel,0.],/DATA,/TO_NORMAL)
        nwid=!X.WINDOW(1)-!X.WINDOW(0)
        nht=!Y.WINDOW(1)-!Y.WINDOW(0)
        PLOTS,[nxy(0)-0.06*nwid,nxy(0)-0.01*nwid] $
	     ,[nxy(1)+0.01*nht,nxy(1)+0.01*nht] $
	     ,LINESTYLE=nplots,/NORMAL

        nplots=nplots+1
    ENDIF
ENDREP UNTIL quit

RETURN
END