PRINT,'Enter the nominal center wavelength (nm) of the filter'
READ,ncw
defpath=STRING(ncw,FORMAT='(I3,"/")')	; create default path
; read file of wavelengths, common to both zenith angles
zafile=defpath+'signal.za'
openr,1,zafile & readf,1,c,r & d=fltarr(c,r)
readf,1,d & close,1 & d=transpose(d)
w=d(*,0) & icen=d(*,1) & ecen=d(*,2) & iedg=d(*,3) & eedg=d(*,4)
mnic=MIN(icen,MAX=mxic)
icen=(icen-mnic)/(mxic-mnic) & ecen=ecen/(mxic-mnic)
mnie=MIN(iedg,MAX=mxie)
iedg=(iedg-mnie)/(mxie-mnie) & eedg=eedg/(mxie-mnie)
PRINT,STRING(MIN(w,MAX=wmx),wmx, $
      FORMAT='("Data span wavelengths from ",F5.1," nm to ",F5.1," nm;")')
PRINT,'Enter limits for wavelength axis'
READ,wlo,whi		; get user input
!p.title=STRING(ncw, $
         FORMAT='(I3," nm Filter in Optics Module")')
!x.title="Wavelength ( nm )"
!y.title="Relative Transmission"
PLOT,w,icen,XRANGE=[wlo,whi],YRANGE=[0,1.35],XSTYLE=1,YSTYLE=1
ERRPLOT,w,icen+ecen,icen-ecen	; plot error bars on 0 deg z.a. curve
OPLOT,w,iedg,line=2
ERRPLOT,w,iedg+eedg,iedg-eedg
top=!Y.CRANGE(1)		; upper limit of Y (camera signal) axis
wrange=whi-wlo			; length of X (wavelength) axis
; put descriptive legend on graph
PLOTS,[wlo+0.05*wrange,wlo+0.15*wrange],[1.25,1.25]
XYOUTS,wlo+0.17*wrange,1.25,'0 !9%!x zenith angle'
PLOTS,[wlo+0.05*wrange,wlo+0.15*wrange],[1.2,1.2],linestyle=2
XYOUTS,wlo+0.17*wrange,1.2,'57 !9%!x zenith angle'
END